CD School House 9/CD School House 9.0 - Wayzata Technology (1994).iso/pc/games/dos/adven/gscape/sample.in3

Text File | 1993-11-18 | 12KB | 742 lines

>REMAR
SAMPLE ADVENTURE-- COMMAND SECTION.
SEE ALSO SAMPLE.IN1 AND SAMPLE.IN2
FLAG LIST:
1   0-FUSE NOT IN  1-FUSE IN.
2   0-DON'T ALLOW TELEPORT  1-ALLOW TELEPORT
3   0-FUSEBOX CLOSED  1-FUSEBOX OPEN
4   0-HAVEN'T NOTICED BLOWN FUSE  1-HAVE NOTICED BLOWN FUSE
101 # OF MOVES (DEFAULT OF FLAG 101)
IMPORTANT NOTE!  Always write down on a
list somewhere (or comment in your code)
exactly what purpose you're assigning to
your flags.  You'll never remember without it!
<

>COMND
* *                          COMAS, COLONS: AND "QUOTES" ARE ALLOWED IN
IF                           COMMENTS!  "AIN'T, THAT: GREAT?"
FLAG>
101
50                           If more than 50 moves game is lost.
DO
PRINT
18
END
<

>COMND
S *
IF
AT
5
FLAG=                        If south from computer room and no teleport,
2                            send back to main room.
0
DO
GOTO
1
SHOW
<

>COMND
N *
IF
AT                           North from lit supply room.
6
DO
GOTO
1
SHOW
<

>COMND
N *
IF
AT
1
FLAG=                        If try to go N at main room and fuse not in
1                            tell them it is dark and leave them
0                            in main room
DO
PRINT
15
<

>COMND
DROP *
DO                           Drop any item anywhere
DROP
<

>COMND
N *
IF
AT
1                            If north from center room
FLAG=
1                            and fuse is in and door closed
1
FLAG=
3
0
DO                           go to computer room
GOTO
5
SHOW
<

>COMND
E *
IF
AT
1                            If east from main room
DO                           go to cluttered room
GOTO
4
SHOW
<

>COMND
S *
IF
AT
1                                 If go south from central room
FLAG=                             and energy is on go to room 6
3                                 instead of room 3!
0
FLAG=
1
1
DO
GOTO
6
SHOW
<

>COMND
S *
IF
AT                           If south from center room
1                            go to supply room
DO
GOTO
3
SHOW
<

>COMND
W *
IF
AT
1                            If west from center room
DO                           go to observatory
GOTO
2
SHOW
<

>COMND
E *
IF
AT
2
DO                           If east from observatory
GOTO                         go to center room
1
SHOW
<

>COMND
N *
IF
AT
3                            If north from utility room
DO                           go to center room
GOTO
1
SHOW
<

>COMND
W *
IF
AT
4
DO                           If west from cluttered room
GOTO                         go to center room
1
SHOW
<

>COMND
S *
IF
AT
3
DO                           If south from unlit supply room go to monster
GOTO                         room and munch 'em
7
SHOW
END
<

>COMND
S *
IF
AT                           If south from lit supply room, do the same.
6
DO
GOTO
7
SHOW
END
<


>COMND
SEARCH TELESCOPE
IF
AT                           If paper doesn't exist yet and
2                            telescope is searched tell them
NOTEXIST                     they've found paper and move the
1                            paper into the room
DO
GRAPH
8
PRINT
2
OBJ
1
2
<

>COMND
SEARCH TELESCOPE
IF
AT                           If they search the telescope after they've
2                            found the paper show them something else.
PRESENT
1
DO
PRINT
4
<

>COMND
READ PAPER
IF
EXIST                        If they read the paper and they have the
1                            paper, tell them what it says.
302
DO
PRINT
36
<

>COMND
OPEN FUSEBOX
IF
AT                           If they open a closed fusebox
3                            tell them they did so!
FLAG=
3
0
DO
FLAGSET
3
1
PRINT
5
<

>COMND
OPEN FUSEBOX
IF
AT                           If they try to open an open fusebox
3                            tell them they're senile.
FLAG=
3
1
DO
PRINT
6
<

>COMND
SEARCH FUSEBOX
IF                                If the fusebox is searched
AT                                and the fusebox is closed
3                                 and the fuse isn't in
FLAG=                             then tell them the
3                                 fusebox is closed.
0
FLAG=
1
0
DO
PRINT
23
<

>COMND
SEARCH FUSEBOX
IF
AT                                If the fusebox is searched
3                                 after the fuse is in
FLAG=                             and if the fusebox is still
1                                 open tell them the fusebox
1                                 is open and looking good.
FLAG=
3
1
DO
PRINT
24
<

>COMND
SEARCH FUSEBOX
IF
AT
3
FLAG=
3
1                            If they search an open fusebox
FLAG=
4                            and they haven't seen the blown fuse yet
0
DO
PRINT                        tell them a fuse is blown and
7
FLAGSET
4                            set flag for having seen blown fuse.
1
<

>COMND
SEARCH FUSEBOX
IF
AT
3
FLAG=                        If they search the fusebox
3                            and it is open
1
FLAG=
4                            and they've already seen a fuse is blown
1
DO
PRINT                        tell them so!
8
<

>COMND
SEARCH FUSEBOX
IF                           If they search the fusebox
AT
3
FLAG=                        and the fusebox is open
3
1
FLAG=
1                            and they've fixed the fuse
1
DO
PRINT                        tell them they see an open fusebox.
21
<

>COMND
OPEN BOXES
IF
AT
3
FLAG=
1
0
NOTEXIST
3
DO
PRINT
31
<

>COMND
SEARCH BOXES
IF
AT
3                            If they search boxes and a fuse
NOTEXIST                     does not exist tell them they find
3                            a fuse and move the fuse into the room.
DO                           (If fuse doesn't exist, they haven't found it
PRINT                        before, which means it exists in the box!)
9
OBJ
3
3
<

>COMND
SEARCH BOXES
IF                           If they search the boxes but they've
AT                           already picked up the fuse tell
3                            them they're looped.
EXIST
3
302
DO
PRINT
10
<

>COMND
REPLACE FUSE
IF                           If they replace the fuse
AT
3
EXIST                        and they have the fuse to use
3
302
FLAG=
3                            and fusebox is open
1
DO
PRINT
3                            tell them they've fixed the fuse
FLAGSET
1                            set the fuse as being replaced
1
OBJ
3                            and move the fuse to limbo.
301
<

>COMND
REPLACE FUSE
IF
AT                           If they tru to replace the fuse but the
3                            fusebox is closed then tell them
FLAG=                        the fusebox is closed.
3
0
EXIST
3
302
DO
PRINT
23
<

>COMND
REPLACE FUSE                 If they try to replace a fuse they
IF                           don't own let them know.
AT
3
NOTEXIST
3
DO
PRINT
22
<

>COMND
CLOSE FUSEBOX
IF
AT
3                            If they close the fusebox
FLAG=                        and it is open
3
1
FLAG=                        and fuse hasn't been replaced
1
0
DO
FLAGSET
3                            shut the fusebox door
0
PRINT                        and tell them OK you've shut it!
3
<

>COMND
CLOSE FUSEBOX
IF
AT
3                            If try to close the fusebox
FLAG=                        and the fusebox is open
3
1
FLAG=
1                            and the fuse is in place
1
DO
FLAGSET
3                            Close the fusebox
0
GOTO                         and send them to room 6.
6
SHOW
<

>COMND
36-24-36 *
IF
AT
4                            If they open the safe
EXIST
1                            and have the paper
302
DO
PRINT                        tell them they've done so and
12
OBJ                          move the disk into the safe.
2
4
<

>COMND
OPEN SAFE
IF
AT                           If they try to just open the safe
4
DO                           tell them it's a locked safe.
PRINT
13
<

>COMND
GET DISKETTE
IF
NOTEXIST                     If they get the disk and it's not around
2
DO                           tell them they're screwy.
PRINT
14
<

>COMND
INSERT DISKETTE
IF
AT                           If they insert the disk
5
FLAG=                        and the fuse is replaced
1
1
FLAG=                        and the fusebox door closed
3
0
EXIST
2                            and the disk exists
302
DO
PRINT                        Tell them the place is live with energy
16
FLAGSET
2                            Set the teleport flag on.
1
<

>COMND
EXAM COMPUTER                If exam computer describe.
IF
AT
5
DO
PRINT
33
<

>COMND
INVENTORY *                  List their inventory.
DO
INVEN
<

>COMND
LOOK *
DO                           Show the current location.
SHOW
<

>COMND
END *
DO                           End the game.
END
<

>COMND
QUIT *                       Quit the game.
DO
QUIT
<

>COMND
S *
IF
AT
5
FLAG=                        If they go south and
2                            the teleporter is on
1                            tell them they win the game.
DO
GOTO
8
SHOW
PRINT
1
END
<

>COMND
HELP *                            Display the help screen.
DO
PRINT
19
PRINT
32
<

>COMND
GET TELESCOPE                If they try to get the
IF                           telescope, tell them it's
DO                           too durn heavy!
PRINT
28
<

>COMND
GET BOXES
IF
AT                           If they try to get the boxes
3                            tell them they rattle.
NOTEXIST
3
DO
PRINT
27
<

>COMND
SEARCH DESK
IF                           If they search the desk tell them
AT                           they are wasting their time.
4
DO
PRINT
20
<

>COMND
OPEN DESK
IF
AT                           Does the same thing as SEARCH DESK
4                            only it works with OPEN DESK instead.
DO                           It's not often this is needed but once
PRINT                        in a while it's the only way to cover
20                           all bases!
<

>COMND
SEARCH SAFE
IF
AT                           If they search the safe and
4                            the diskettes don't exist, tell them
NOTEXIST                     there's a big, heavy safe and show it
2
DO
GRAPH
9
PRINT
25
<

>COMND
SEARCH SAFE
IF                           If they search the safe after
AT                           finding the disk show them the
4                            open safe and tell them there's a diskette
PRESENT
2
DO
GRAPH
11
PRINT
37
<

>COMND
SEARCH BLONDE
IF                           If they search the blonde
AT                           tell them they're a pervert.
2
EXIST
1
302
DO
PRINT
29
<

>COMND
GET BLONDE
IF                           If they get the blonde, kill them.
AT
2
DO
PRINT
30
END
<

>COMND
READ SIGN
IF
AT                           Can't read a sign in the dark.
3
DO
PRINT
34
<

>COMND
READ SIGN
IF
AT
6                            Now they can read the sign.
DO
PRINT
35
<

>COMND
SAVE *
DO                           Save the game
SAVE
<

>COMND
LOAD *
DO
LOAD                         Load a previous game
<

>COMND
GET *
DO
OBJ                          STANDARD GET FUNCTION
0
302
INVEN
<


>COMND
* *
DO
PRINT                        If words OK but illogical
17                           tell them about it.
<

>ENDIN